;
; IR Decode
; Decode and display NEC IR codes
; Derived from IR Widget
; 2006-10-19 Revision 1.00
;
; Keivn Timmerman
; irwidget [@t] compendiumarcana [d0t] com
; www.compendiumarcana.com/irwidget
;



	include <P12F629.INC>
	#define FIRSTREG 0x20
	#define PGMSIZE 1024

													; Configuration bits
	__config _CPD_OFF & _CP_OFF & _BODEN_ON & _MCLRE_OFF & _PWRTE_ON & _WDT_ON & _INTRC_OSC_CLKOUT

	errorlevel -220									; Stupid MPLAB complains about IDLOCS
	org		0x2000									; IDLOCS
	;dw		'I','R','D','0'							; IR Decode Rev 0
	errorlevel +220


BANK1		equ 0x80								; Reduce assembler whining

	radix dec										; Default radix of decimal


													; --- I/O
													; 8 Ground
													;
bMode			equ	0								; 7
pMode			equ GPIO							;
bSerTx			equ	1								; 6 Serial data to host PC
pSerTx			equ	GPIO							;
bIRDetect		equ	2								; 5 IR Detector module input
pIRDetect		equ	GPIO							;
bDTR			equ	3								; 4 DTR
pDTR			equ	GPIO							;
bOscOut			equ	4								; 3 Osc Out
													;
bIRDemod		equ	5								; 2 IR Demodulator module input
pIRDemod		equ	GPIO							;
													; 1 Power
													;
asio_out_port	set	pSerTx
asio_out_bit	set	bSerTx


	cblock FIRSTREG									; Registers
	last_time
	asio_data
	asio_flags
	asio_bit_time
	temp1
	time_save
	ir_state
	ir_bit
	ir_data0
	ir_data1
	ir_data2
	ir_data3
	endc

	org		0x0000									; - Start of program memory

	nop												;
	clrf	GPIO									; All outputs off
	goto	skip_isr								; Jump over the ISR
													;
	org		0x0004									; - ISR
	goto	$										; Let the watchdog handle this
													;
													;
skip_isr											;
													; - Initiailize periferals
													;
													;
	movlw	(1<<CM0) | (1<<CM1) | (1<<CM2)			; Disable comparator
	movwf	CMCON									;
													;
	call	PGMSIZE-1								; Get OSCCAL
													;
	bsf		STATUS,RP0								; Bank 1
													;
	movwf	OSCCAL ^ BANK1							; Setup OSCCAL
													;
#ifdef ANSEL										;
	movlw	(1<<ADCS0) | (1<<ADCS2)					; Make all pins digital I/O
	movwf	ANSEL ^ BANK1							;
#endif												;
													;
	movlw	(1<<bIRDetect) | (1<<bIRDemod) | (1<<bMode) | (1<<bDTR)	; Setup TRIS
	movwf	TRISIO ^ BANK1							;
													;
	;movlw	(1<<bIRDetect) | (1<<bIRDemod) | (1<<bMode) | (1<<bDTR)	; Setup WPU
	errorlevel -219									;
	movwf	WPU	^ BANK1								;
	errorlevel +219									;
													;
													; *GPPU = 0 - WPU enabled
													; INTEDG = 0
													; T0CS = 0 - Internal clock source
													; T0SE = 0 - Inc on rising edge
													; PSA = 0 - Assign prescaller to TMR0
													; PSx - Prescaler = 5 (1:64) 15625 Hz
	movlw	5										;
	movwf	OPTION_REG ^ BANK1						;
													;
	bcf		STATUS,RP0								; Bank 0
													;
													;
													; - Initialize registers
													; 
	clrf	last_time								; Init last pulse time
													;
													; Setup bit rate
	movlw	0xFF									; 57600 bps (special case)
	movwf	asio_bit_time							;
													;
													;
													; ----- Pulse time capture -----
													;
ptwf												; - Wait for falling edge
	clrwdt											;
	btfsc	pIRDemod,bIRDemod						;
	goto	ptwf									;
													; - Send elapsed time to host
	movf	last_time,W								; Get last time
	subwf	TMR0,W									; Subtract last time from current time
													; W now holds elapsed time
	addwf	last_time,F								; Update last time
	btfsc	pDTR,bDTR								;
	call	decode									; Call decoder state machine
	btfss	pDTR,bDTR								;
	call	asio_tx									;
													;
ptwr												; - Wait for rising edge
	clrwdt											;
	btfss	pIRDemod,bIRDemod						;
	goto	ptwr									;
													;
	goto	ptwf									; Loop...
													;
													;
													;
													;
decode												; ----- Decode NEC IR Protocol -----
													;
	movwf	time_save								; Save the pulse time
	movf	ir_state,W								; Get state
	andlw	0x07									; Limit to safe values
	addwf	PCL,F									; Jump to state...
	goto	necs0									;
	goto	necs1									;
	goto	necs2									;
	goto	necs3									;
	goto	necs4									;
	goto	necs5									;
	goto	necs6									;
	goto	necs7									;
													;
necs5												;
necs6												;
necs7												;
necs0												; - State 0 - Lead in
													; 13500 uS typical
													; Allow 1228 to 15040
													; 192 to 235 counts
	clrf	ir_state								; Stay in this state
	movf	time_save,W								; Get pulse time
	addlw	-236									; Less than 236?
	btfsc	STATUS,C								;
	retlw 	0										; No, 236 to 255, exit state
	addlw	236-192									; Less than 192?
	btfss	STATUS,C								;
	retlw	0										; Yes, 0 to 191, exit state
													; 192 to 235, Valid start time
	incf	ir_state,F								; Next state
	clrf	ir_bit									; Clear bit count
	retlw	0										;
													;
necs1												; - State 1 - Decode 0/1
													; Zero bit - 1125 uS typical
													; Allow 896 to 1408
													; 14 to 22 counts
													; One bit - 2250 uS typical
													; Allow 1920 to 2560
													; 30 to 40 counts
	movf	time_save,W								;
	addlw	-41										; Less than 41?
	btfsc	STATUS,C								;
	goto	necs0									; No, 41 to 255, goto state 0
	addlw	41-30									; Less than 30?
	btfsc	STATUS,C								;
	goto	necbit									; No, 30 to 40, One bit, carry is set so shift in a data bit...
	addlw	30-23									; Less than 23?
	btfsc	STATUS,C								;
	goto	necs0									; No, 23 to 30, goto state 0
	addlw	23-14									; Less than 14?
	btfss	STATUS,C								;
	goto	necs0									; Yes, 0 to 13, goto state 0
	bcf		STATUS,C								; 14 to 22, Zero bit
necbit												;
	rrf		ir_data3,F								; Shift a bit into IR data - LSB first
	rrf		ir_data2,F								;
	rrf		ir_data1,F								;
	rrf		ir_data0,F								;
	incf	ir_bit,F								; Inc bit count
	movf	ir_bit,W								;
	xorlw	32										; 32 bits done?
	btfss	STATUS,Z								;
	retlw	0										; No...
													;
													; - Complete 32 bit code received
	incf	ir_state,F								; Inc state
													;
													; Send IR code to host in ASCII hex format
	movlw	' '										;
	call	asio_tx									;
	movf	ir_data3,W								;
	call	tx_hex									;
	movf	ir_data2,W								;
	call	tx_hex									;
	movf	ir_data1,W								;
	call	tx_hex									;
	movf	ir_data0,W								;
	call	tx_hex									;
	movlw	' '										;
	call	asio_tx									;
	retlw	0										;
													;
													;
necs2												; - State 2 - Lead out
	incf	ir_state,F								; Next state
	retlw	0										;
													;
necs3												; - State 3 - Repeat
													; 11250 uS typical
													; Allow 10048 to 12224
													; 157 to 191 counts
	movf	time_save,W								;
	addlw	-192									; Less than 192?
	btfsc	STATUS,C								;
	goto	necs0									; No, 192 to 255, goto state 0
	addlw	192-157									; Less than 157?
	btfss	STATUS,C								;
	goto	necs0									; Yes, 0 to 156, goto state 0
													; 157 to 191
	incf	ir_state,F								;
	retlw	0										;
													;
necs4												; - State 4 - Repeat
													; Time may vary, so don't check it
	decf	ir_state,F								; Previous state
	movlw	' '										;
	call	asio_tx									; Send " Rpt " to host
	movlw	'R'										;
	call	asio_tx									;
	movlw	'p'										;
	call	asio_tx									;
	movlw	't'										;
	call	asio_tx									;
	movlw	' '										;
	call	asio_tx									;
	retlw	0										;
													;
													;
													;
tx_hex												; ------ Send byte to host as ASCII hex -----
	movwf	temp1									;
	swapf	temp1,W									; Get MSB
	call	tx_nibble								; Send it
	movf	temp1,W									; Get LSB
	;goto	tx_nibble								; Send it
													;
													;
tx_nibble											; ----- Send nibble to host as ASCII hex -----
	andlw	0x0F									; Mask LSB
	addlw	-10										; Test for >=10
	btfsc	STATUS,C								;
	addlw	'A'-('0'+10)							; >=10, use offset of 'A'
	addlw	'0'+10									; Offset of '0'
	;goto		asio_tx								;
													;
													;
													;
													;
													; ----- Async serial transmission -----
asio_tx												;
	bsf		asio_out_port,asio_out_bit				; Start bit
	clrwdt											; Clear watchdog
	movwf	asio_data								; Move W to tx data register
	movlw	9										; 8 data bits + stop bit
	movwf	asio_flags								;
	call	asio_delay								; Wait one bit time
	nop												;
asiotbl												;
	rrf		asio_data,F								; Shift out a bit
	btfsc	STATUS,C								; Is it a zero?
	goto	$+4										; No..
	nop												; Precise timing
	bsf		asio_out_port,asio_out_bit				;
	goto	$+3										;
	bcf		asio_out_port,asio_out_bit				;
	goto	$+1										;
	call	asio_delay								; Wait one bit time
	decfsz	asio_flags,F							; Dec bit count
	goto	asiotbl									; Not zero, do next bit...
	retlw	0										; Return
													;
													;
													;
asio_delay											; --- Delay N + 14 cycles with one cycle granularity
													;  Special case of 0xFF will delay only 9 cycles
													; W=1, C=1 upon exit
													;
	comf	asio_bit_time,W							; Get compliment of bit time to W
	bsf		STATUS,C								; Carry must be set upon exit
	btfsc	STATUS,Z								; Test for special case of max bit rate (0xFF)
	retlw	1										; Max rate, exit without delay...
	btfsc	asio_bit_time,0							; Add one cycle if bit 0 of bit time is set
	goto	$+1										;
	btfss	asio_bit_time,1							; Add two cycles if bit 1 of bit time is set
	goto	$+3										;
	goto	$+1										;
	nop												;
#ifdef CORE12										;
	addwf	four,W									; 12 bit core lacks addlw, so use addwf with a constant
													;  stored in a register
#else												;
	addlw	4										; Add 4 to W until overflow
#endif												;
	btfss	STATUS,C								;  Each loop interation takes 4 cycles
	goto	$-2										;
	retlw	1										; Set W to 1 and return
													;
													;
													;
	end												;
													;