PIC Microcontoller Basic Math Multiplication Methods

• 8x8 bit from Andrew Warren
• 8x8 bit from unknown author (please step forward)
• 8x8 bit from Scott Dattalo with small correction by Dmitry Kiryashov
• 16x8 bit from Dingbat
• 16x16 bit macro from Bob Fehrenbach, Scott Dattalo
• 16x16 bit From Clyde Smith-Stubbs of HI-TECH software
• 16x16 bit from Ravi Pailoor
• 16x16 bit from Jim Bixby Unsigned, fast (16x16 mpy in about 168 instructions):
• 16x16 bit from malin. Signed.
• 16x16 bit from malin. Unsigned
• 24x8 bit from Byron A Jeff
• 24x24bit from Nikolai Golovchenko
• 24x24bit from Fred Maher with Tutorial
• Tutorial1 Logic based
• Tutorial2 Math based
• Multiplication and/or division by a Constant
  • The PICList code generator
  • Binary Multiplication by a Constant
  • 8 bits by a constant by Myke Predko
• (8 bits * 256) / 8 bits by Nikolai Golovchenko

• See also:

  • http://www.iversoft.com/piclist/9802/0021.shtml
  • http://www.myke.com/PICMicro/16bit.htm

Archive:

• PICList post "18 series vs. 16 series" How to multiply two 16 bit values useing only 3 multiplications +
• PICList post "multiplication routing 24x8"
• PICList post "Looking for improved integer's math routines"

4x4 bit multiply

; 4x4 bit multiply
; result in W
; by  John Payson
       movlw   0
       bcf     C
       btfss   n1,0
       addwf   n2,w
       rlf     n2,f
       btfss   n1,1
       addwf   n2,w
       rlf     n2,f
       btfss   n1,2
       addwf   n2,w
       rlf     n2,f
       btfss   n1,3
       addwf   n2,w
       rlf     n2,f
       swapf   n2,f
; 15 cycles, putting the result in W and
; leaving n1 and n2 untouched at the end.
; Striking the requirement that n2 be untouched would save the
; last two cycles.
; Note that if n1<=15 and n1*n2<=255 this routine will ; produce a correct result even if n2>15;
; the value in n2 will be trashed in such a case, though.


; 4x4 bit multiply
; by  John Payson
; result in n2...
       swapf   n1,w    ; Assume top 4 bits zero
       btfss   n2,0
       addwf   n2,f
       rrf     n2,f

If we have Cy=1 before entering this code fragment and we skip first addition we'll got error.

       btfss   n2,0
       addwf   n2,f
       rrf     n2,f
       btfss   n2,0
       addwf   n2,f
       rrf     n2,f
       btfss   n2,0
       addwf   n2,f
       rrf     n2,f
; 13 cycles, leaving the result in n2.
; This one won't work if either factor is oversized.

; 4x4 bit multiply
; by Ray Gardiner
       ;  X*Y ; result left in W
       ;  X and Y are 4 bits
       ;
       ;
       CLRW            ; Clear Result
       CLRC            ; Clear Carry for RLF later                     ;
       BTFSC   Y,0     ; ?*1
       ADDWF   X,W     ; W = ?X
       RLF     X,F     ; X = 2X
                       ;
       BTFSC   Y,1     ; ?*2
       ADDWF   X,W     ; W = ?X + ?2X
       RLF     X,F     ; W = 4X

       BTFSC   Y,2     ; ?*4
       ADDWF   X,W     ; W = ?X + ?2X + ?4X
       RLF     X,F     ; W = 8X

       BTFSC   Y,3     ; ?*8
       ADDWF   X,W     ; ?X + ?2X + ?4X + ?8X
       ;;;;;;;;;;;;;;;;;;;;;;;;;

       13 cycles result in W  13 bytes of code space


Looking back, I now realise that is what John Payson has already
posted. Albeit in a different form. Sigh(!)

;       4 X 4 multiplication
; by Dmitry Kiryashov
       movfw   x       ;0000abcd
       addwf   x,F
       btfss   y,0     ;0000efgh
       movlw   0
       btfsc   y,1
       addwf   x,W
       rlf     x,F
       btfsc   y,2
       addwf   x,W
       rlf     x,F
       btfsc   y,3
       addwf   x,W     ;result in W
;       12 clocks/words

See:

• /techref/piclist/pcbcontest.htm PICList free PCB contest+
• /techref/microchip/dttwist.htm Scott Dattalos' Dual Tone Digital Twist for the PIC+
• /techref/microchip/seepicsrc/psbpix/multiplication.htm , microchip, seepicsrc, psbpix, multiplication+

32-bit signed integer math routines. add, subtract, multiply, divide, round, sqrt, bin2dec, dec2bin. By Peter Hemsley. +

  .